@echo off
rem
rem  version.cmd
rem  Copyright (C) 2007 lolo_32 <pouchintv-dev@baysse.fr>
rem
rem  This file is part of Pouchin TV Mod, a free DVB-T viewer.
rem  See http://pouchintv.baysse.fr/ for updates.
rem
rem  Pouchin TV Mod is free software; you can redistribute it and/or modify
rem  it under the terms of the GNU General Public License as published by
rem  the Free Software Foundation; either version 2 of the License, or
rem  (at your option) any later version.
rem
rem  Pouchin TV Mod is distributed in the hope that it will be useful,
rem  but WITHOUT ANY WARRANTY; without even the implied warranty of
rem  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
rem  GNU General Public License for more details.
rem
rem  You should have received a copy of the GNU General Public License
rem  along with this program; if not, write to the Free Software
rem  Foundation, Inc., 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA
rem
rem
rem  Most files of this project have been changed from the Pouchin TV
rem  project (Copyright (C) 2006 Pouchin <pouchinteve@free.fr>),
rem  to use with a modified version of this software.
rem  See http://pouchinteve.free.fr/ for the original project.
rem

rem Nettoyage pr‚liminaire par pr‚caution :
if exist version_$temp$.txt del version_$temp$.txt

echo ####
rem Cherche si on est dans un repository
if exist .svn\nul (
	rem Extrait la version du SVN utilis‚e
	svnversion -cn 2>NUL > version_$temp$.txt
	if errorlevel 1 (
		echo #### L'utilitaire "svnversion", qui fait partie de "Subversion", n'est pas disponible,
		echo #### ou bien mal install‚ : le num‚ro de version ne peut pas ˆtre g‚n‚r‚ correctement.
		echo #### Pour disposer de cet utilitaire, veuillez t‚l‚charger et installer un package
		echo #### binaire de "Subversion" … l'adresse suivante : http://subversion.tigris.org/
		echo #### Suite … cette installation, vous devrez alors avoir la commande "svnversion"
		echo #### disponible dans le "PATH" en ligne de commande.
		echo #### N'utilisez pas celui de "Cygwin" car problŠme avec les caractŠres accentu‚s.
		echo ####
		if exist version_$temp$.txt del version_$temp$.txt
	)
)

rem G‚n‚ration du num‚ro de version dans un fichier "version_$temp$.h",
rem ainsi que dans une variable d'environnement :
if exist version_$temp$.txt (
	type version_$temp$.txt | tools\GeneRealVersion.exe version_$temp$.h version "SET SVN_VERSION=" > set_version_$temp$.cmd
	del version_$temp$.txt
) else (
	rem Version export‚e, tout est d‚j… OK
	echo nS | tools\GeneRealVersion.exe version_$temp$.h version "SET SVN_VERSION=" > set_version_$temp$.cmd
)
call set_version_$temp$.cmd
del set_version_$temp$.cmd
echo %SVN_VERSION%> version.txt

rem G‚n‚ration d'un fichier d'inclusion pour le num‚ro de version dans l'installeur
echo ; Ce fichier est généré automatiquement par 'version.cmd'> version.nsh
echo.>> version.nsh
echo !define PRODUCT_VERSION "%SVN_VERSION%">> version.nsh

rem Comparaison de "version_$temp$.h" avec le fichier "version.h" courant.
rem S'ils sont diff‚rents, "version_$temp$.h" devient le nouveau "version.h"
rem (ainsi la date de modification "version.h" ne change que si c'est appropri‚)
rem
echo n | comp version_$temp$.h version.h 2>NUL >NUL
rem Code retour : 0 = fichiers identiques, 1 = fichiers diff‚rents, 2 = fichier inexistant
if errorlevel 1 (
	if exist version.h del version.h
	ren version_$temp$.h version.h
	echo #### Un nouveau fichier de version "version.h" a ‚t‚ g‚n‚r‚
) else (
	del version_$temp$.h
)

rem Affichage de la version compil‚e
echo #### Version compil‚e: %SVN_VERSION%
echo ####

rem On recherche le type de compilateur : Express ou Studio
tools\ConditionalHeaderGenerator 3 > vstudio_edition_$TEMP$.h

rem Comparaison de "vstudio_edition_$TEMP$.h" avec le fichier "vstudio_edition.h" courant.
rem S'ils sont diff‚rents, "vstudio_edition_$TEMP$.h" devient le nouveau "vstudio_edition.h"
rem (ainsi la date de modification "vstudio_edition.h" ne change que si c'est appropri‚)
rem
echo n | comp vstudio_edition_$TEMP$.h vstudio_edition.h 2>NUL >NUL
rem Code retour : 0 = fichiers identiques, 1 = fichiers diff‚rents, 2 = fichier inexistant
if errorlevel 1 (
	if exist vstudio_edition.h del vstudio_edition.h
	ren vstudio_edition_$TEMP$.h vstudio_edition.h
	echo #### Un nouveau fichier "vstudio_edition.h" d'identification du compilateur a ‚t‚ g‚n‚r‚
) else (
	del vstudio_edition_$TEMP$.h
)